Fortran动态链接库DLL和静态库Lib之间Common 数据和文件逻辑单元共享

EnSafe · 发表于 2013-5-7 22:55:27

1、摘要

在对CHEMKIN的二次开发中，需要访问Common数据块，并需要将文件逻辑单元传入原软件。通过测试，发现只能通过静态库进行逻辑单元共享。

测试结论如下：

(1) 主程序可以访问动态库的Common数据，前提是动态库必须导出Common区的符号。主程序和动态链接库的文件逻辑单元不可共享。
(2) 动态链接库之间可以共享Common数据，前提是其中的一个动态库必须导出Common区的符号。动态链接库之间可以共享文件逻辑单元。
(3) 静态库之间可以实现Common数据和文件逻辑单元的共享。

以下为测试的源程序及其说明。

2、主程序和动态链接库之间的数据共享

示例程序：

1_DataShareMainDLL.rar (232.18 KB, 下载次数: 48717)

2013-5-8 10:50 上传

点击文件名下载附件

主程序可以访问动态库的Common数据，前提是动态库必须导出Common区的符号。主程序和动态链接库的文件逻辑单元不可共享。本例中，即使在主文件打开了文件单元Unit 7，在DLL打开了文件单元Unit 8，在另外的程序文件中的写入操作没有写入到打开的文件，而是重新创建了 fort.8 和 fort.7。

主程序和DLL共享 Common 的方法如下：

(1) 在DLL.f90的任何一个过程导出Common的符号：

!DEC$ Attributes DllExport :: /IntegerData/

(2) 在Main.f90中的任何一个过程导入Common的符号：

!DEC$ Attributes DllImport :: /IntegerData/

程序代码如下：

在 CommonData.fh 中定义 Common 块 IntegerData

Integer iData
Common /IntegerData/ iData

在DLL中定义函数（DLL.f90）

Subroutine DLLGetData(iDataGet)
!DEC$ Attributes DllExport :: DLLGetData, /IntegerData/
Implicit None
Include 'CommonData.fh'
Integer iDataGet
iDataGet = iData
Write(*,*) 'DLL message: Common data read. iData= ', iData
End Subroutine

Subroutine DLLOpenFile(LOut,strFileName)
!DEC$ Attributes DllExport :: DLLOpenFile
Implicit None
Integer LOut
CHARACTER *(*) strFileName
Open(LOut, File=strFileName)
Write(*,*) 'DLL message: Open file unit ', LOut
Write(LOut,*) 'DLL message: Open file unit ', LOut
End Subroutine

Subroutine DLLCloseFile(LOut)
!DEC$ Attributes DllExport :: DLLCloseFile
Implicit None
Integer LOut
Write(*,*) 'DLL message: Close file unit ', LOut
Write(LOut,*) 'DLL message: Close file unit ', LOut
Close(LOut)
End Subroutine

Subroutine DLLWriteTest(LOut)
!DEC$ Attributes DllExport :: DLLWriteTest
Implicit None
Include 'CommonData.fh'
Integer LOut
Write(LOut, *)  'DLL Message: Write unit ', LOut, ' iData=', iData
End Subroutine

主程序Main.f90如下：

Subroutine MainOpenFile(LOut,strFileName)
Implicit None
Integer LOut
Character*(*) strFileName
Open(LOut, File=strFileName)
Write(*,*) 'Main message: Open file unit ', LOut
Write(LOut,*) 'Main message: Open file unit ', LOut
End Subroutine

Subroutine MainCloseFile(LOut)
Implicit None
Integer LOut
Write(*,*) 'Main message: Close file unit ', LOut
Write(LOut,*) 'Main message: Close file unit ', LOut
Close(LOut)
End Subroutine

Subroutine MainWriteTest(LOut)
Implicit None
Include 'CommonData.fh'
Integer LOut
Write(LOut, *)  'Main Message: Write unit ', LOut, ' iData=', iData
End Subroutine

Subroutine MainSetData(iDataSet)
Implicit None
Include 'CommonData.fh'
Integer iDataSet
iData = iDataSet
Write(*,*) 'Main program message: Common data iData=: ', iData
End Subroutine

Program Test
!DEC$ Attributes DllImport :: /IntegerData/
Implicit None
Include 'CommonData.fh'
!Include 'Test.fh'
Integer :: LOutMain = 7
Integer :: LOutDLL = 8
Integer :: iDataS = 2
Integer iDataR

! 分别在主程序和DLL中打开文件
Call DLLOpenFile(LOutDLL, "OutDLL.txt")
Call MainOpenFile(LOutMain, "OutMain.txt")
! 测试 Common 数据读取
Call MainSetData(iDataS)
Call DLLGetData(iDataR)
Write(*,*) 'Main program message: Data retrived iDataR=: ', iDataR
! 分别在 Main 中写 Main 中打开的逻辑单元，在DLL中写 DLL 中打开的文件
Call DLLWriteTest(LOutDLL)
Call MainWriteTest(LOutMain)
! 分别在 Main 中写 DLL 中打开的逻辑单元，在 DLL中写 Main 中打开的文件
Call DLLWriteTest(LOutMain)
Call MainWriteTest(LOutDLL)

! 关闭文件
Call DLLCloseFile(LOutDLL)
Call MainCloseFile(LOutMain)
Read *
End Program

3、动态链接库之间的数据共享

动态链接库之间可以共享Common数据，前提是其中的一个动态库必须导出Common区的符号。动态链接库之间可以共享文件逻辑单元。

本例源程序：

2_DataShare2DLL.rar (359.37 KB, 下载次数: 49697)