Fortran 导出函数调用另一个导出函数的接口声明方法

EnSafe

讨论了一个函数是另一个函数的外部函数，同时该函数为导出函数的情况下，如何在调用函数中声明该函数的接口。

本例源代码下载： Exported_External_Function.rar (14.23 KB, 下载次数: 51878)

2011-10-13 22:55 上传

点击文件名下载附件

假定有两个Swap和Sort，均为导出函数。Sort调用Swap。假如我们在Sort中声明External Swap。编译器报告找不到_SWAP：
”错误 1  error LNK2019: 无法解析的外部符号 _SWAP，该符号在函数 Sort 中被引用 Source2.obj“。

其原因是Swap函数的属性进行了修改：!DEC$ Attributes DllExport, StdCall,Reference, Alias:'Swap'::Swap，函数内部名称为 Swap，而在Sort函数中，Swap被默认定义为_SWAP。


Swap子程序如下。同时采用StdCall和Reference属性，参数按引用传递。

Subroutine Swap(A,B)
!DEC$ Attributes DllExport, StdCall,Reference, Alias:'Swap'::Swap
Implicit None
Double Precision A,B
Double Precision T
T=A
A=B
B=T  
End Subroutine

包含不正确的外部函数声明的Sort函数如下：

Subroutine Sort(A,N)
!DEC$ Attributes DllExport,StdCall,Alias:'Sort'::Sort
Implicit None
Double Precision A(N)
Integer N
External Swap  ! It doesn't work
Integer I,J,N1
N1=N-1
Do I=1,N1
       Do J=I+1,N
              If(A(I)>A(J))    Call Swap(A(I),A(J))
       End Do
End Do
End Subroutine ! End of Sort

包含正确的外部函数接口声明的Sort函数如下：

Subroutine Sort(A,N)
!DEC$ Attributes DllExport,StdCall,Alias:'Sort'::Sort
Implicit None
Double Precision A(N)
Integer N
!External Swap   ! It doesn't work
! The interface works
Interface
Subroutine Swap(A,B)
!DEC$ Attributes DllExport, StdCall,Reference, Alias:'Swap'::Swap
Double Precision A,B
End Subroutine
End Interface
Integer I,J,N1
N1=N-1
Do I=1,N1
       Do J=I+1,N
              If(A(I)>A(J))    Call Swap(A(I),A(J))
       End Do
End Do
End Subroutine ! End of Sort

在C#中队导出函数的声明为：

        [DllImport("FDLL.dll", CallingConvention = CallingConvention.StdCall)]
        public static extern void Swap(ref double A, ref double B);
        [DllImport("FDLL.dll", CallingConvention = CallingConvention.StdCall)]
        public static extern void Sort(double[] A, int N);